Περιεχόμενα

# Συνάρτηση AGGREGATE

Αυτή η συνάρτηση επιστρέφει ένα συνολικό αποτέλεσμα των υπολογισμών στην περιοχή. Μπορείτε να χρησιμοποιήσετε διαφορετικές συγκεντρωτικές συναρτήσεις που αναφέρονται παρακάτω. Η συγκεντρωτική συνάρτηση σας επιτρέπει να παραλείψετε τις κρυφές γραμμές, σφάλματα, SUBTOTAL και άλλα αποτελέσματα της συνάρτησης AGGREGATE στον υπολογισμό.

Η συνάρτηση AGGREGATE εφαρμόζεται σε κάθετες περιοχές δεδομένων με ενεργοποιημένο το αυτόματο φίλτρο. Αν το αυτόματο φίλτρο δεν είναι ενεργό, ο αυτόματος επανυπολογισμός του αποτελέσματος της συνάρτησης δεν δουλεύει για τις πρόσφατες κρυμμένες γραμμές. Δεν προβλέπεται να δουλεύει με οριζόντιες περιοχές, όμως μπορεί να εφαρμόζεται και σε αυτές, αλλά με περιορισμούς. Ειδικά, όταν η συνάρτηση AGGREGATE εφαρμόζεται σε μια οριζόντια περιοχή δεδομένων δεν αναγνωρίζει τις κρυμμένες στήλες, όμως παραλείπει σωστά σφάλματα και αποτελέσματα των συναρτήσεων SUBTOTAL και άλλων συναρτήσεων AGGREGATE που είναι ενσωματωμένα στη γραμμή.

### Σύνταξη

AGGREGATE(Συνάρτηση; Επιλογή; Αριθμός 1[; Αριθμός 2][; ... ;[Αριθμός 253]])

ή

AGGREGATE(Συνάρτηση; Επιλογή; Πίνακας[; k])

Συνάρτηση – υποχρεωτικό όρισμα. Ένας δείκτης συνάρτησης ή μια αναφορά σε ένα κελί με τιμή από 1 μέχρι 19, σύμφωνα με τον παρακάτω πίνακα.

Ευρετήριο συναρτήσεων | Εφαρμοσμένη συνάρτηση
--- | ---
1 | AVERAGE
2 | COUNT
3 | COUNTA
4 | MAX
5 | MIN
6 | PRODUCT
7 | STDEV.S
8 | STDEV.P
9 | SUM
10 | VAR.S
11 | VAR.P
12 | MEDIAN
13 | MODE.SNGL
14 | LARGE
15 | SMALL
16 | PERCENTILE.INC
17 | QUARTILE.INC
18 | PERCENTILE.EXC
19 | QUARTILE.EXC

Επιλογή – υποχρεωτικό όρισμα. Ένας δείκτης επιλογής ή αναφορά σε ένα κελί με τιμή από 0 έως 7 καθορίζει τι να αγνοείται στο πεδίο τιμών για τη συνάρτηση.

Δείκτης επιλογής | Εφαρμοσμένη επιλογή
--- | ---
0 | Παράβλεψη μόνο των ένθετων συναρτήσεων SUBTOTAL και AGGREGATE
1 | Παράβλεψη μόνο των κρυμμένων γραμμών, των ένθετων συναρτήσεων SUBTOTAL και AGGREGATE
2 | Παράβλεψη μόνο των σφαλμάτων, των ενσωματωμένων συναρτήσεων SUBTOTAL και AGGREGATE
3 | Παράβλεψη των κρυμμένων γραμμών, σφαλμάτων, των ενσωματωμένων συναρτήσεων SUBTOTAL και AGGREGATE
4 | Να μην παραβλέπεται τίποτα
5 | Να παραβλέπονται μόνο οι κρυμμένες γραμμές.
6 | Να παραβλέπονται μόνο τα σφάλματα.
7 | Να παραβλέπονται μόνο οι κρυμμένες γραμμές και τα σφάλματα.

Αριθμός1 – απαραίτητο όρισμα. Το πρώτο αριθμητικό όρισμα (εάν η περιοχή έχει οριστεί από κατάλογο τιμών μέσα στη συνάρτηση) ή αναφορά σε κελί που την περιέχει.

Αριθμός2, 3, … – προαιρετικό. Αριθμητικό όρισμα ή αναφορά σε κελί (μέχρι 253 ορίσματα), για τα οποία χρειάζεστε τη συγκεντρωτική τιμή.

Πίνακας – απαιτούμενο όρισμα. Ο πίνακας μπορεί να οριστεί από τα όρια της περιοχής, το όνομα της ονοματισμένης περιοχής ή την ετικέτα στήλης.

Για τη χρήση των ετικετών στηλών της συνάρτησης πρέπει να ενεργοποιηθεί το “Αυτόματη εύρεση ετικετών στηλών και γραμμών”.

k – απαιτούμενο όρισμα για τις παρακάτω συναρτήσεις: LARGE, SMALL, PERCENTILE.INC, QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC. Είναι αριθμητικό όρισμα, που πρέπει να αντιστοιχεί στο δεύτερο όρισμα αυτών των συναρτήσεων.

### Παραδείγματα

| A | B | C
1 | ΠρώτηΣτήλη | ΔεύτερηΣτήλη | ΤρίτηΣτήλη
2 | 34 | 11 | 12
3 | 10 | 56 | 35
4 | #ΔΙΑΙΡ/0! | 5 | 3
5 | 20 | 8 | 1
6 | 0 | 8 | 9
7 | #ΤΙΜΗ! | 20 | 21
8 | 5 | 7 | 8
9 | 14 | 0 | 5

=AGGREGATE(4;2;A2:A9)
Επιστρέφει τη μέγιστη τιμή για το εύρος A2:A9 = 34.

=AGGREGATE(9;5;A5:C5)
Επιστρέφει το άθροισμα για την περιοχή A5:C5 = 29, ακόμα κι αν κάποιες από τις στήλες είναι κρυμμένες.

=AGGREGATE(9;5;B2:B9)
Επιστρέφει το άθροισμα της στήλης B = 115. Αν οποιαδήποτε γραμμή είναι κρυφή, η συνάρτηση παραλείπει την τιμή της, π.χ. εάν η 7η γραμμή είναι κρυφή, η συνάρτηση επιστρέφει 95.

Αν χρειάζεται να εφαρμόσετε τη συνάρτηση με μια περιοχή 3Δ, αυτό το παράδειγμα δείχνει πώς να το κάνετε.

=AGGREGATE(13;3;Φύλλο1.B2:B9:Φύλλο3.B2:B9)
Η συνάρτηση επιστρέφει την κατάσταση των τιμών των δεύτερων στηλών από τα φύλλα 1:3 (που έχουν τα ίδια δεδομένα) = 8.

Μπορείτε να χρησιμοποιήσετε μια αναφορά σε ένα κελί ή μια περιοχή για κάθε όρισμα στον τύπο. Το παρακάτω παράδειγμα εμφανίζει πώς δουλεύει. Επιπλέον, εμφανίζει ότι μπορείτε να χρησιμοποιήσετε τις ετικέτες της στήλης για να ορίσετε έναν πίνακα.

=AGGREGATE(E3;E5;'Στήλη1')
Εάν E3 = 13 και E5 = 5, η συνάρτηση επιστρέφει την κατάσταση της πρώτης στήλης = 10.

#### Τεχνικές πληροφορίες

Αυτή η συνάρτηση είναι διαθέσιμη από το LibreOffice 4.4.

Αυτή η συνάρτηση δεν αποτελεί μέρος του προτύπου Open Document Format for Office Applications (OpenDocument) Έκδοση 1.3. Μέρος 4: Μορφή επανυπολογισμένου τύπου (OpenFormula). Ο χώρος του ονόματος είναι

COM.MICROSOFT.AGGREGATE

Σχετικά θέματα

Σελίδα βίκι AGGREGATE.

AVERAGE, COUNT, COUNTA, MAX, MIN, PRODUCT, STDEV.S, STDEV.P, SUM, VAR.S, VAR.P, MEDIAN, MODE.SNGL, LARGE, SMALL, PERCENTILE.INC , QUARTILE.INC, PERCENTILE.EXC, QUARTILE.EXC

Αυτόματη εύρεση ετικετών στηλών και γραμμών